Adding a new item to a list json using Visual Basic

Question

so I'm building an app and I'm reading a JSON file so I can add a new reservation but after searching online I didn't find any way to add a new dict to a list using visual basic and Newtonsoft.JSON.

The json file:

{"reservations": [{"time": "07:00 pm", "tableId": "1", "clientName": "Antonio Goncalves", "status": "pending"}]}

Basically I want to add a new dictionary of values inside the reservations list.

The current function

Public Sub SetReservation(time As String, tableId As String, clientName As String, Optional status As String = "pending")
        Dim reservationFile As String = File.ReadAllText(reservationJsonFile)

        If Not String.IsNullOrEmpty(reservationFile) And Not String.IsNullOrWhiteSpace(reservationFile) Then
            Dim reservationJson = Linq.JObject.Parse(reservationFile)
            Dim newReservationObject = Linq.JObject.FromObject(New Dictionary(Of Object, Object) From {{"time", time}, {"tableId", tableId}, {"clientName", clientName}, {"status", status}})

            Trace.WriteLine(newReservationObject)
        End If
    End Sub

You should make a reservation object and deserialize the json into a List(Of Reservation). Then you can simply add a new reservation to the list, serialize it and save to file. — Anu6is
– Anu6is, Commented Nov 27, 2021 at 10:19

Anu6is · Accepted Answer · 2021-11-27 10:58:40Z

Creating Classes that represent your json makes working with the json a lot simpler. See the classes created to represent your json data and how it's would be utilized in your sub routine.

'Root object representing the "reservations" key in the json file
Public Class ReservationData
    Public Property Reservations As List(Of Reservation)
End Class

'Properties match the expected keys in the json file
Public Class Reservation
    Public Property Time As String
    Public Property TableId As String
    Public Property ClientName As String
    Public Property Status As String
End Class

Comments included as additional explanations.

Public Sub SetReservation(time As String, tableId As String, clientName As String, Optional status As String = "pending")
    Dim reservationFile As String = File.ReadAllText(reservationJsonFile)

    If Not String.IsNullOrWhiteSpace(reservationFile) Then
        'Convert the json string to a ReservationData object
        Dim reservationData = JsonConvert.DeserializeObject(Of ReservationData)(reservationFile)
        'Create a new Reservation
        Dim newReservation = New Reservation With {.Time = time, .TableId = tableId, .ClientName = clientName, .Status = status}

        'Access the Reservations list from reservationData and Add the new Reservation
        reservationData.Reservations.Add(newReservation)

        'Overwrite the file with the updated reservationData
        File.WriteAllText(reservationJsonFile, JsonConvert.SerializeObject(reservationData))
    End If
End Sub

Collectives™ on Stack Overflow

Adding a new item to a list json using Visual Basic

1 Answer 1

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

1 Answer 1

Comments

Your Answer

Sign up or log in

Post as a guest

Related