Check if substring exist in string from cmd/bat script

Question

I want to check if count exists in mycountry or not, and then do some operations according.

My code snippet :

rem @ECHO OFF
cls
SET FILE="mycountry"

If true I want to run 3 statements and if false I want to run 3 other statements.

I have tried this combination:

Echo.%FILE% | findstr /C:"count">nul && (Echo.TRUE) || (Echo.FALSE)

But how to write multiple statements if the condition gets true? I don't wanna use any flag variable.

Below snippet is not working.

Echo.%FILE% | findstr /C:"count">nul && 
(
Echo.TRUE
echo "ran correct."
) 
|| (Echo.FALSE)

Do you want to check if a substring exists in a variable or in a textfile? — double-beep
– double-beep, Commented Dec 26, 2018 at 14:29
The snippet fails to work because the opening parenthesis of the code block has to be on the same line as the conditional execution && (... and also ) || (... BTW here it doesn't matter, but don't inject a space in front of the pipe symbol Echo.%FILE%| findstr — user6811411
– user6811411, Commented Dec 26, 2018 at 17:05
Correct @LotPings, however the OP also states that they've 'tried this combination', Echo.%FILE% | findstr /C:"count">nul && (Echo.TRUE) || (Echo.FALSE), which has parentheses on the correct line, and therefore does not exhibit the issue! My suspicion is that they've not provided accurate information in their question body. — Compo
– Compo, Commented Dec 26, 2018 at 17:40
I interpret I have tried this combination versus Below snippet is not working that the 1st did work, the latter not. — user6811411
– user6811411, Commented Dec 26, 2018 at 17:45

Laurens Deprost · Accepted Answer · 2018-12-26 14:23:06Z

4

You can use the %errorlevel% value combined with an if/else.
See the example below:

REM @echo off
cls
SET FILE="mycountry"
SET STR="TEST"

findstr %STR% %FILE% >nul
if %errorlevel% equ 1 (
    goto searchError
) else (
    goto searchSucces
)

:searchSucces
echo String %STR% found in file %FILE%
pause
exit

:searchError
echo String %STR% not found in file %FILE%
pause
exit

answered Dec 26, 2018 at 14:23

Laurens Deprost

1,7017 silver badges16 bronze badges

Sign up to request clarification or add additional context in comments.

Comments

Compo · Accepted Answer · 2018-12-31 10:02:07Z

Your code, (integrated into a batch file), appears to work as expected:

@Echo Off

Set "FILE="

Set /P "FILE=Enter String: "

If Not Defined FILE Exit /B

Echo.%FILE% | findstr /C:"count">nul && (Echo.TRUE) || (Echo.FALSE)

Pause

In addition, the following two methods both appear to work as expected:

Using Echo and FindStr (as in your code):

@Echo Off

Set "FILE="

Set /P "FILE=Enter String: "

Echo=%FILE%|FindStr /IC:"count">Nul 2>&1&&(Echo TRUE
    Echo Ran correct.
    Timeout 3 /NoBreak>Nul
    Echo Still running!)||Echo FALSE
Pause

Using variable substitution:

@Echo Off

Set "FILE="

Set /P "FILE=Enter String: "

If /I "%FILE:count=%"=="%FILE%" (Echo FALSE) Else (Echo TRUE
    Echo Ran correct.
    Timeout 3 /NoBreak>Nul
    Echo Still running!)
Pause

If the examples above do not work for you, you should edit your question to include the actual code and strings you're using in your real world scenario. We cannot fix something we cannot see, especially if you don't fully explain the issue, (snippet is not working is a statement only, not an explanation).

Collectives™ on Stack Overflow

Check if substring exist in string from cmd/bat script

2 Answers 2

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

2 Answers 2

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related