"Haskell" way of modifying a character in an array of strings?

Question

I'm not sure if our assignment was presented in the most functional-enabling of ways, but I have to work with it. I have a "map" that represents a pacman game state:

B B B B
B P _ B
B . . B
B B B B

where B is a border tile, P is pacman, _ is an empty space, and . is a food pellet. There are many rules when moving pacman, but consider one:

When pacman moves into a tile occupied by a food pellet, replace the pacman tile with an empty space and the food pellet with pacman. This function would have the definition:

move:: [[Char]] -> [[Char]]

Right now I've got functions that give me the (x,y) coordinate tuple of pacman and his new location, and I was planning to use the !! function to "overwrite" the tiles. However, I know a little of list operations such as :. Could I use : to accomplish this task?

Gabriella Gonzalez · Accepted Answer · 2013-11-15 23:30:25Z

2

Rather than modify the string, I would instead define a function of type:

type Position = (Int, Int)
type Board = [[Char]]

renderBoard :: Position -> Board

Then I would just modify pacman's position and re-render the board:

move :: Position -> Position

Edit: To answer your specific question, you can do this easily using the lens library:

import Control.Lens

move :: Position -> Position -> Board -> Board
move (oldX, oldY) (newX, newY) = (ix oldX.ix oldY .~ '_') . (ix newX.ix newY .~ 'P')

edited Nov 15, 2013 at 23:30

answered Nov 15, 2013 at 23:24

Gabriella Gonzalez

35.2k3 gold badges80 silver badges138 bronze badges

Sign up to request clarification or add additional context in comments.

4 Comments

Caleb Jares Over a year ago

Nice tip on design, but I'm stuck with the professor's declarations unfortunately.

Gabriella Gonzalez Over a year ago

Updated to answer your specific question

Caleb Jares Over a year ago

What does ix and .~ stand for? Also, correct me if I'm wrong; is the . operator taking the changed board on the left and using that in the next lens replacement?

Gabriella Gonzalez Over a year ago

@CalebJares ix means "index" and (.~) is like a function setter. The idea is that the left argument of (.~) tells it what to set, and in this case it says "Set the char located at outer index oldX and inner index oldY". The right argument of .~ is what to set it to (in this case, _). It's a functional setter, meaning that it produces a function of type [[Char]] -> [[Char]]. I take two such functions and compose them using function composition, which is what the (.) is doing.

Ankur · Accepted Answer · 2013-11-16 08:32:11Z

0

Below is a replace function that you can use to replace a particular position character in the 2d array [[Char]]

replace :: [[Char]] -> (Int,Int) -> Char -> [[Char]]
replace chars (x',y') c = do
  (x,row) <- zip [0..] chars
  return [if x == x' && y == y' then c else r | (y,r) <- zip [0..] row]

The second argument is the position which needs to be updated with the Char value in 3rd position.

Using this function you should be able to implement your move function.

answered Nov 16, 2013 at 8:32

Ankur

33.7k2 gold badges50 silver badges73 bronze badges

Comments

Chris Taylor · Accepted Answer · 2013-11-16 09:07:58Z

Here's a simple approach that doesn't rely on libraries. First, we define a function .~ that allows you to set the index of a list -

set n x xs = take n xs ++ (x : drop (n+1) xs)

and give it a convenient alias so that we can use it in infix form.

n .~ x = \xs -> set n x xs

This allows you to do things like

>> let list = [1,2,3,4]
>> 1 .~ 10 $ list
[1,10,3,4]

Now it's a simple matter to extend that to a function that modifies two-dimensional lists

(n,m) .= x = \xs -> n .~ (m .~ x $ xs!!n) $ xs

so that you can do things like

>> let listOfList = [[1,2,3],[4,5,6],[7,8,9]]
>> (1,1) .= 100 $ listOfList
[[1,2,3],[4,100,6],[7,8,9]]

Now you can easily write a function move that takes an old position, a new position and the current board, and modifies the board in the way you want

type Pos   = (Int,Int)
type Board = [[Char]]

move :: Pos -> Pos -> Board -> Board
move (x,y) (x',y') board = board''
  where
    board'  = (x, y ) .= '_' $ board
    board'' = (x',y') .= 'P' $ board'

That is, the first line in the where clause modifies the board to replace PacMan's old position with an empty space, and the second line modifies the board that's reutrned form that, to put PacMan in the new position.

Collectives™ on Stack Overflow

"Haskell" way of modifying a character in an array of strings?

3 Answers 3

4 Comments

Comments

Comments

Your Answer

Hot Network Questions

Collectives™ on Stack Overflow

3 Answers 3

4 Comments

Comments

Comments

Your Answer

Sign up or log in

Post as a guest

Related