Merging two JSON objects into new sorted list in ASP.NET

Given the OP's updated code, here's an alternate solution using SortedDictionary. Note that there will be some dropped messages that have the same created_time to the millisecond. Mostly these would likely be msgs received previously, but there could be a tiny bit of coincidental loss.

Imports Newtonsoft.Json
Imports System.Timers
Imports System.Net

Module Module2

    Friend WithEvents Timer1 As New Timers.Timer(5000)

    Private OrderedPosts As New SortedDictionary(Of DateTime, FBFeed)
    Private AccessToken As String = "Your Token Goes Here"

    Sub Main()
        Timer1.Enabled = True
        Console.ReadKey()
    End Sub

    Private Sub Timer1_Elapsed(sender As Object, e As ElapsedEventArgs) Handles Timer1.Elapsed
        GetPosts("OI.Plavipingvin", AccessToken)
        GetPosts("217384491624554", AccessToken)

        Debug.Print("Msg Count: {0}", OrderedPosts.Count.ToString)
        For Each Post As FBFeed In OrderedPosts.Values
            Debug.Print("{0}{1}{2}", Post.created_time, vbTab, Post.message)
        Next
        Debug.Print("")
    End Sub

    Private Sub GetPosts(PageId As String, accessToken As String)
        Dim APIlink As String = String.Format("https://graph.facebook.com/{0}/posts?fields=full_picture,message,created_time,id,link,type,name,description&access_token={1}", PageId, accessToken)

        Using WebClient As New WebClient()
            WebClient.Encoding = Text.Encoding.UTF8

            With JsonConvert.DeserializeObject(Of FBData)(WebClient.DownloadString(APIlink))
                For Each Post As FBFeed In .data
                    Try
                        OrderedPosts.Add(Post.created_time, Post)
                    Catch ex As Exception
                        Debug.Print("Duplicate post created_time: {0}", Post.created_time.ToString("O"))
                    End Try
                Next
            End With
        End Using
    End Sub

    Private Class FBData
        Public Property data As New List(Of FBFeed)
    End Class

    Private Class FBFeed
        Public Property message As String
        Public Property created_time As DateTime
        Public Property id As String
        Public Property type As String
        Public Property name As String
    End Class

End Module

So, thanks to @MrGadget help I come to solution to my problem, just because I couldn't find whole solution anywhere on the net.

Dim accessToken As String= appID & "|" & appSecret

Dim array1 As FBData = GetPosts ( "OI.Plavipingvin", accessToken )
Dim array2 As FBData = GetPosts ( "217384491624554", accessToken )

'Merging two lists
array1.data.AddRange(array2.data.ToArray)

'Order final list
'Dim OrderedPosts as List(Of FBFeed) = array1.data.OrderByDescending(Function(x) x.created_time)

For Each Msg As FBFeed In array1.data.OrderByDescending(Function(x) x.created_time)
    Response.Write( Msg.created_time & "<br />" )
    Response.Write( "<image width=""100px"" height=""100px"" src=""" & Msg.full_picture & """><br />" )
Next

And here are FBData Class and function to get and serialise JSON.

Public Class FBData
    Public Property data As New List(Of FBFeed)
End Class

Public Class FBFeed
    Public Property full_picture As String
    Public Property message As String
    Public Property created_time As DateTime
    Public Property id As String
    Public Property link As String
    Public Property type As String
    Public Property name As String
    Public Property description As String
End Class

Public Shared Function GetPosts( PageId As String, accessToken As String ) As FBData

    Dim APIlink As String = "https://graph.facebook.com/" & pageID & "/posts?fields=full_picture,message,created_time,id,link,type,name,description&access_token=" & accessToken

    Dim client As New WebClient()
    client.Encoding = System.Text.Encoding.UTF8
    Dim strJson As [String] = client.DownloadString(APIlink)

    Dim result As FBData = Newtonsoft.Json.JsonConvert.DeserializeObject(Of FBData)( strJson )

    Return result

End Function